Final Project Documentation (Shane Leonard)

/*


Morse Code Bluetooth

This sketch creates a Bluetooth morse code clicker. To translate a message to morse code, power up the device (it does not have to be physically connected to your computer) and open the Arduino Serial Monitor to the correct Bluetooth port (it should be something like /dev/tty.linvor-DevB or /dev/cu.linvor-DevB). You can type any (lowercase) message and send it over the Serial port, and the Arduino will respond with a morse code representation of the message. If you have a speaker connected to pin 9, this message will also be played on the speaker.

Copyright Shane Leonard (2013) under the Creative Commons License. This software is released as open source, so you have full permission to duplicate and redistribute any portion of this code.

*/


int speakerPin = 9;
// letters are a max of 4 morse characters
String alphabet = "abcdefghijklmnopqrstuvwxyz1234567890";
String morseAlphabet[] = {".-", "-...", "-.-.","-..",".","..-.","--.",
"....","..",".---","-.-",".-..","--","-.","---",".--.","--.-",".-.",
"...","-","..-","...-",".---","..--",".---","-..",".----","..---",
"...--","....-",".....","-....","--...","---..","----.","-----"};

int NUM_CHARS = 36; // length of the 'alphabet'

int t_int = 50; // duration of the morse code dot

void playTone(int tone, int duration) {
  for (long i = 0; i < duration * 1000L; i += tone * 2) {
    digitalWrite(speakerPin, HIGH);
    delayMicroseconds(tone);
    digitalWrite(speakerPin, LOW);
    delayMicroseconds(tone);
  }
}


void playNote(char note, int duration) {
  char names[] = { 'c', 'd', 'e', 'f', 'g', 'a', 'b', 'C' };
  int tones[] = { 1915, 1700, 1519, 1432, 1275, 1136, 1014, 956 };
 
  // play the tone corresponding to the note name
  for (int i = 0; i < 8; i++) {
    if (names[i] == note) {
      playTone(tones[i], duration);
    }
  }
}


void dot() {
  Serial1.write('.');
  digitalWrite(13, HIGH);
  playNote('c', t_int);
  digitalWrite(13, LOW);
  delay(t_int);
}


void dash() {
  Serial1.write('-');
  digitalWrite(13, HIGH);
  playNote('c', 3 * t_int);
  digitalWrite(13, LOW);
  delay(3 * t_int);
}


void letter_space() {
  Serial1.write(' ');
  delay(3 * t_int);
}

void word_space() {
  Serial1.write('/');
  delay(7 * t_int);
}

String charToMorse(char ch) {
  if (ch == ' ') return "/"; // word space
 
  for (int i = 0; i < NUM_CHARS; i++) {
    if (ch == alphabet[i]) {
      return (morseAlphabet[i] + " "); // the space indicates the end of a letter
    }
  }
  return "/"; // return a word space by default
}


void playMorse(String morse) {
  for (int i = 0; i < morse.length(); i++) {
    char ch = morse[i];
    if (ch == '.') dot();
    else if (ch == '-') dash();
    else if (ch == ' ') letter_space();
    else if (ch == '/') word_space();
  }
}


void setup() {
  Serial1.begin(9600);
  pinMode(speakerPin, OUTPUT);
}

void loop() {
  while(!Serial1.available()) {}
  char ch = Serial1.read();
  String morse = charToMorse(ch);
  playMorse(morse);
}

/*
  SD card file dump

 This example shows how to read a file from the SD card using the
 SD library and send it over the serial port.

 The circuit:
 * SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 17 (listed on Micro as SS)

 created  22 December 2010
 by Limor Fried

 modified 9 Apr 2012
 by Tom Igoe

 modified 1 May 2013
 by Harry Johnson
 
 modified 11 June 2013
 by Shane Leonard

 This example code is in the public domain.
 */

#include <SPI.h>
#include <SD.h>

//On the Arduino Micro, the SS pin is defined in software as pin 17.
const int chipSelect = 17;

void setup()
{
 // Open serial communications and wait for port to open:
  Serial.begin(9600);

  delay(1000); //this 1 second delay isn't strictly speaking necessary, but it seems to smooth over the USB serial monitor a bit.
  while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }

  Serial.print("Initializing SD card...");
  pinMode(17, OUTPUT); //set SS pin as output.

  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    return;
  }

  Serial.println("card initialized.");

  initializeFile();
 
  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
  File dataFile = SD.open("datalog.txt");

  // if the file is available, write to it:
  if (dataFile) {
    while (dataFile.available()) {
      Serial.write(dataFile.read());
    }
    dataFile.close();
  } 

  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  }
}


// Ensure that the file "datalog.txt" exists and that it is initialized with
// sample data
void initializeFile() {
  if (SD.exists("datalog.txt")) {
    SD.remove("datalog.txt");
  }
 
  File dataFile = SD.open("datalog.txt", FILE_WRITE);
  dataFile.write("This is a sample sentence to make sure your SD card is set up correctly.");
  dataFile.close();
}

void loop()
{

}